# Praat-Skript für Praat 4.2
# Auslesen von Pitchwerten in allen Dateien eines gegebenen Verzeichnisses
# Methode: Erzeugung eines Pitchobjektes
# Bestimmung von 10 Pitchwerten im Abstand von 100ms
# nichtdefinierte Werte werden durch 0 ersetzt
# Stefan Sudhoff, sudhoff(at)uni-leipzig.de, 01/2004


# Festlegen des Verzeichnisses
verz$ = "D:\praat\"

# Laden von allen wav-Dateien
Create Strings as file list... dateien 'verz$'\*.wav
anz = Get number of strings
for filenr from 1 to anz
	select Strings dateien
	Sort
	aktstr$ = Get string... filenr
	aktdat$ = aktstr$ - ".wav"
	Read from file... 'verz$''aktdat$'.wav
endfor

# Schleife für jede Datei, Auslesen der Pitchwerte
for filenr from 1 to anz
	# Auswahl des jeweiligen Items
	select Strings dateien
	Sort
	aktstr$ = Get string... filenr
	aktdat$ = aktstr$ - ".wav"

	# Angabe des Filenamens in der Ausgabedatei
	fileappend "cont1.txt" 'newline$''newline$''aktdat$''newline$''newline$'

	#Selektion von jeweils einer wav-Datei, Anlegen eines Pitchobjektes, Auslesen der Pitchwerte
	select Sound 'aktdat$'
	To Pitch... 0.001 75 600
	select Pitch 'aktdat$'
	for schritt from 0 to 10
		pos = 'schritt' * 0.1
		pit = Get value at time... 'pos' Hertz Linear
		if pit = undefined
			pit = 0
		endif
		fileappend "cont1.txt" 'pos:3''tab$''pit:0''newline$'
	endfor

	# Löschen von Sound und Pitchobjekt aus der Objektliste
	select Sound 'aktdat$'
	Remove
	select Pitch 'aktdat$'
	Remove
endfor

# Löschen des Objekts mit den Dateinamen
select Strings dateien
Remove